Contract 0x5130ca61bf02618548dfc3fdef50b50b36b11f2b

Txn Hash Method
Block
From
To
Value [Txn Fee]
0xdca85d9489d027d2e0e612c44a590c5b3897ac4f908f44c468efe6864e939689Transfer28889332023-02-06 6:12:3019 hrs 35 mins ago0x78adffe94747fdb8fcadb1a9167bfba775fe7f96 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.003809295
0xa4fc77d94a342c0605e5c493cd07b0f68bbe1c15fd4b729b62ac10aa1803d362Transfer28794612023-02-04 22:13:122 days 3 hrs ago0xb8950c47e8b9e539601cb47a167de8bf4cb1289e IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.00382806
0xb8a79b50cee6647686546bed5e2febbc4e0774f5f02bbc7f66685ce699088ce6Approve28425922023-01-30 17:18:487 days 8 hrs ago0x0bbdf4faab833f953313d4099437cff950592b87 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005480391
0x16cb3a2a2f0ec9e19d34dbc41f16ad66322bd75ca1c0b1b95986add048773cd0Approve27951122023-01-24 0:14:2414 days 1 hr ago0x795500f92412e806fc504d666d158a74f313505a IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005509623
0xd4b50dcb3ad3c97e14380af464de4c41e0f44aa6a1b4ce0cd030fdd4cb758ed8Approve27937772023-01-23 19:43:0014 days 6 hrs ago0xa148ecbffcab78e728bf3093accb1abc44235b14 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005482827
0xdb6650454eebe5235053393a3e58af17ed00cc00d54112c97cf6ff5a3e87c36aTransfer27937092023-01-23 19:28:5414 days 6 hrs ago0x4d45f3fb1564033af6a01eb2a2367f0c021afdc8 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.003804423
0xa32e7fa08ac7fb816d033dcb4979140db78f1a4997a9baa5bf9e4a40f79dd848Transfer27936502023-01-23 19:17:0614 days 6 hrs ago0xa148ecbffcab78e728bf3093accb1abc44235b14 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.006027273
0xcb8ba3d0da920ed042a2c58a9ae7cedb059fa077ad2a05dbaeb64e8ac3d2dedbApprove27903532023-01-23 8:02:0014 days 17 hrs ago0x32d9b5c41d594838d6b993ebaf538ff770a00e30 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005509623
0xb60731e65145bca815d2c06946a4f6bb2b708c15dc594becff173e8dba398932Approve27565292023-01-18 13:27:3619 days 12 hrs ago0xda651a390f94e4055f20a3be11e6211b6983dcde IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005531925
0xc2ffe175aeaff13c85d61d42103136c6f22d9394f693cf25cda5aa249b882614Approve27564402023-01-18 13:09:3619 days 12 hrs ago0x553de6c52ca165f63196b5dd80817f8636d029ac IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005534385
0xe36a5743029997fcba9dd07b11c1f9171b7d527a9225b251fe3626d43382eb89Transfer27564312023-01-18 13:07:4819 days 12 hrs ago0xe9249b01e193b2d8aa8b9ac7cd33ded0033fe735 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.004295277
0x767522fe396f7bf7df1ed23caa1f980cd4e20d1459ecfa2e104504054c0fde39Approve27564142023-01-18 13:04:2419 days 12 hrs ago0x553de6c52ca165f63196b5dd80817f8636d029ac IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005533155
0xfd9604bf2da4a06c972af77892820f2ed8568fd682e8a0e88a4280b342f64123Approve27561952023-01-18 12:20:1819 days 13 hrs ago0x4cb920450e418c982c40d1e07dfab445b0d1b055 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005531925
0x4d304abd61adfff879d94b72eca0743a09c381c93ffee4b2d1c6db3e839dfce6Approve27549062023-01-18 7:58:0619 days 17 hrs ago0x1665235630f8fd617dcc32599f47fd36e51d1b77 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005533155
0x4eb8cd084b1cb189229156dc1ca19ef20644a63b7760238dbe57a678a7f0e94eApprove27544202023-01-18 6:17:5419 days 19 hrs ago0x4cb920450e418c982c40d1e07dfab445b0d1b055 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005533155
0xbf26f9ffeca86e50866a696780dd7ae6ea0e4adfd6f94eeb3325e6487ff317bbApprove27530662023-01-18 1:42:1220 days 5 mins ago0x91719e7835b707b9300f7e0f08ba4878ad456fe9 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.003493405
0x369776e1330e6f25c51926039d216f85a5cfd3a7c088cdd66493ca8fca81b351Approve27530532023-01-18 1:39:3020 days 8 mins ago0x91719e7835b707b9300f7e0f08ba4878ad456fe9 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005533155
0xc7d43bc528aa44b30415ec064da06d5945cad754ac2975697cd141e227b46e66Approve27506182023-01-17 17:24:1220 days 8 hrs ago0x5159a8216bf820bc3643f0df0c11aa030db5c8b3 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.003780405
0x648c7e9e54f7e0a2473d05388a917fb40fec93c82f406d00b95bbf3e36fd627eApprove27506122023-01-17 17:23:0020 days 8 hrs ago0x5159a8216bf820bc3643f0df0c11aa030db5c8b3 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.003780405
0xce63133ff60c1ec98fb51f3a560b788ae65cfbf1de72416261b617845f5313b7Approve27493212023-01-17 12:54:0620 days 12 hrs ago0xe3a04324597838ea978a5383b5f593f1386c9e03 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005531925
0x7b0f63914c707ae551eb609d4c09e644e592902a5739a71e08b1b92faf644a8cApprove27475112023-01-17 6:43:1220 days 19 hrs ago0x8e03d193b0d5ea8d2b30bb9891aa423da261a01c IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.003492175
0x27ea4dfb9066d2ae1f8a736ec83b25dbac2f61e565852350eac9f73af097fc98Approve27474702023-01-17 6:35:0020 days 19 hrs ago0x8e03d193b0d5ea8d2b30bb9891aa423da261a01c IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005534385
0x04482651df4c86e9055fcd1732e17bd73693183b2d531aa066657a1e099dc3e2Approve27456202023-01-17 0:20:5421 days 1 hr ago0x8e03d193b0d5ea8d2b30bb9891aa423da261a01c IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005477955
0x346d4d78f56923cdcf9cb813fea798ef67503599aacfe4752f4479bf6ae0eaa8Transfer27455302023-01-17 0:02:4821 days 1 hr ago0x8e03d193b0d5ea8d2b30bb9891aa423da261a01c IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.006027273
0xad46cc3937989bfcb3cd3b9f5e0c641933cce35e457f750a2f6cb44e44693cfdApprove27442262023-01-16 19:39:1821 days 6 hrs ago0x50ed348f85de0772a61ff63bbe33df8db30de1b2 IN  0x5130ca61bf02618548dfc3fdef50b50b36b11f2b0 GLMR0.005531925
[ Download CSV Export 
Latest 1 internal transaction
Parent Txn Hash Block From To Value
0x8da02bcc29dbd3f66fb97ca2bc6037e19047f745279de889e21c797efc6d05d06034182022-03-14 18:47:36329 days 7 hrs ago Nomad: Deployer  Contract Creation0 GLMR
[ Download CSV Export 
Loading

Similar Match Source Code
Note: This contract matches the deployed ByteCode of the Source Code for Contract 0x30D2a9F5FDf90ACe8c17952cbb4eE48a55D916A7

Contract Name:
UpgradeBeaconProxy

Compiler Version
v0.7.6+commit.7338295f

Optimization Enabled:
Yes with 999999 runs

Other Settings:
default evmVersion
File 1 of 2 : UpgradeBeaconProxy.sol
// SPDX-License-Identifier: MIT
pragma solidity >=0.6.11;

// ============ External Imports ============
import {Address} from "@openzeppelin/contracts/utils/Address.sol";

/**
 * @title UpgradeBeaconProxy
 * @notice
 * Proxy contract which delegates all logic, including initialization,
 * to an implementation contract.
 * The implementation contract is stored within an Upgrade Beacon contract;
 * the implementation contract can be changed by performing an upgrade on the Upgrade Beacon contract.
 * The Upgrade Beacon contract for this Proxy is immutably specified at deployment.
 * @dev This implementation combines the gas savings of keeping the UpgradeBeacon address outside of contract storage
 * found in 0age's implementation:
 * https://github.com/dharma-eng/dharma-smart-wallet/blob/master/contracts/proxies/smart-wallet/UpgradeBeaconProxyV1.sol
 * With the added safety checks that the UpgradeBeacon and implementation are contracts at time of deployment
 * found in OpenZeppelin's implementation:
 * https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/proxy/beacon/BeaconProxy.sol
 */
contract UpgradeBeaconProxy {
    // ============ Immutables ============

    // Upgrade Beacon address is immutable (therefore not kept in contract storage)
    address private immutable upgradeBeacon;

    // ============ Constructor ============

    /**
     * @notice Validate that the Upgrade Beacon is a contract, then set its
     * address immutably within this contract.
     * Validate that the implementation is also a contract,
     * Then call the initialization function defined at the implementation.
     * The deployment will revert and pass along the
     * revert reason if the initialization function reverts.
     * @param _upgradeBeacon Address of the Upgrade Beacon to be stored immutably in the contract
     * @param _initializationCalldata Calldata supplied when calling the initialization function
     */
    constructor(address _upgradeBeacon, bytes memory _initializationCalldata)
        payable
    {
        // Validate the Upgrade Beacon is a contract
        require(Address.isContract(_upgradeBeacon), "beacon !contract");
        // set the Upgrade Beacon
        upgradeBeacon = _upgradeBeacon;
        // Validate the implementation is a contract
        address _implementation = _getImplementation(_upgradeBeacon);
        require(
            Address.isContract(_implementation),
            "beacon implementation !contract"
        );
        // Call the initialization function on the implementation
        if (_initializationCalldata.length > 0) {
            _initialize(_implementation, _initializationCalldata);
        }
    }

    // ============ External Functions ============

    /**
     * @notice Forwards all calls with data to _fallback()
     * No public functions are declared on the contract, so all calls hit fallback
     */
    fallback() external payable {
        _fallback();
    }

    /**
     * @notice Forwards all calls with no data to _fallback()
     */
    receive() external payable {
        _fallback();
    }

    // ============ Private Functions ============

    /**
     * @notice Call the initialization function on the implementation
     * Used at deployment to initialize the proxy
     * based on the logic for initialization defined at the implementation
     * @param _implementation - Contract to which the initalization is delegated
     * @param _initializationCalldata - Calldata supplied when calling the initialization function
     */
    function _initialize(
        address _implementation,
        bytes memory _initializationCalldata
    ) private {
        // Delegatecall into the implementation, supplying initialization calldata.
        (bool _ok, ) = _implementation.delegatecall(_initializationCalldata);
        // Revert and include revert data if delegatecall to implementation reverts.
        if (!_ok) {
            assembly {
                returndatacopy(0, 0, returndatasize())
                revert(0, returndatasize())
            }
        }
    }

    /**
     * @notice Delegates function calls to the implementation contract returned by the Upgrade Beacon
     */
    function _fallback() private {
        _delegate(_getImplementation());
    }

    /**
     * @notice Delegate function execution to the implementation contract
     * @dev This is a low level function that doesn't return to its internal
     * call site. It will return whatever is returned by the implementation to the
     * external caller, reverting and returning the revert data if implementation
     * reverts.
     * @param _implementation - Address to which the function execution is delegated
     */
    function _delegate(address _implementation) private {
        assembly {
            // Copy msg.data. We take full control of memory in this inline assembly
            // block because it will not return to Solidity code. We overwrite the
            // Solidity scratch pad at memory position 0.
            calldatacopy(0, 0, calldatasize())
            // Delegatecall to the implementation, supplying calldata and gas.
            // Out and outsize are set to zero - instead, use the return buffer.
            let result := delegatecall(
                gas(),
                _implementation,
                0,
                calldatasize(),
                0,
                0
            )
            // Copy the returned data from the return buffer.
            returndatacopy(0, 0, returndatasize())
            switch result
            // Delegatecall returns 0 on error.
            case 0 {
                revert(0, returndatasize())
            }
            default {
                return(0, returndatasize())
            }
        }
    }

    /**
     * @notice Call the Upgrade Beacon to get the current implementation contract address
     * @return _implementation Address of the current implementation.
     */
    function _getImplementation()
        private
        view
        returns (address _implementation)
    {
        _implementation = _getImplementation(upgradeBeacon);
    }

    /**
     * @notice Call the Upgrade Beacon to get the current implementation contract address
     * @dev _upgradeBeacon is passed as a parameter so that
     * we can also use this function in the constructor,
     * where we can't access immutable variables.
     * @param _upgradeBeacon Address of the UpgradeBeacon storing the current implementation
     * @return _implementation Address of the current implementation.
     */
    function _getImplementation(address _upgradeBeacon)
        private
        view
        returns (address _implementation)
    {
        // Get the current implementation address from the upgrade beacon.
        (bool _ok, bytes memory _returnData) = _upgradeBeacon.staticcall("");
        // Revert and pass along revert message if call to upgrade beacon reverts.
        require(_ok, string(_returnData));
        // Set the implementation to the address returned from the upgrade beacon.
        _implementation = abi.decode(_returnData, (address));
    }
}

File 2 of 2 : Address.sol
// SPDX-License-Identifier: MIT

pragma solidity >=0.6.2 <0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: value }(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    function _verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) private pure returns(bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

Settings
{
  "optimizer": {
    "enabled": true,
    "runs": 999999
  },
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  },
  "libraries": {}
}

Contract ABI

[{"inputs":[{"internalType":"address","name":"_upgradeBeacon","type":"address"},{"internalType":"bytes","name":"_initializationCalldata","type":"bytes"}],"stateMutability":"payable","type":"constructor"},{"stateMutability":"payable","type":"fallback"},{"stateMutability":"payable","type":"receive"}]

60a060405260405161058b38038061058b8339818101604052604081101561002657600080fd5b81516020830180516040519294929383019291908464010000000082111561004d57600080fd5b90830190602082018581111561006257600080fd5b825164010000000081118282018810171561007c57600080fd5b82525081516020918201929091019080838360005b838110156100a9578181015183820152602001610091565b50505050905090810190601f1680156100d65780820380516001836020036101000a031916815260200191505b506040525050506100f0826101d060201b6100291760201c565b610134576040805162461bcd60e51b815260206004820152601060248201526f18995858dbdb880858dbdb9d1c9858dd60821b604482015290519081900360640190fd5b6001600160601b0319606083901b166080526000610151836101d6565b9050610166816101d060201b6100291760201c565b6101b7576040805162461bcd60e51b815260206004820152601f60248201527f626561636f6e20696d706c656d656e746174696f6e2021636f6e747261637400604482015290519081900360640190fd5b8151156101c8576101c881836102d6565b50505061038f565b3b151590565b604051600090819081906001600160a01b0385169082818181855afa9150503d8060008114610221576040519150601f19603f3d011682016040523d82523d6000602084013e610226565b606091505b50915091508181906102b65760405162461bcd60e51b81526004018080602001828103825283818151815260200191508051906020019080838360005b8381101561027b578181015183820152602001610263565b50505050905090810190601f1680156102a85780820380516001836020036101000a031916815260200191505b509250505060405180910390fd5b508080602001905160208110156102cc57600080fd5b5051949350505050565b6000826001600160a01b0316826040518082805190602001908083835b602083106103125780518252601f1990920191602091820191016102f3565b6001836020036101000a038019825116818451168082178552505050505050905001915050600060405180830381855af49150503d8060008114610372576040519150601f19603f3d011682016040523d82523d6000602084013e610377565b606091505b505090508061038a573d6000803e3d6000fd5b505050565b60805160601c6101e06103ab60003980603652506101e06000f3fe60806040523661001357610011610017565b005b6100115b61002761002261002f565b61005f565b565b3b151590565b600061005a7f0000000000000000000000000000000000000000000000000000000000000000610083565b905090565b3660008037600080366000845af43d6000803e80801561007e573d6000f35b3d6000fd5b6040516000908190819073ffffffffffffffffffffffffffffffffffffffff85169082818181855afa9150503d80600081146100db576040519150601f19603f3d011682016040523d82523d6000602084013e6100e0565b606091505b509150915081819061018a576040517f08c379a00000000000000000000000000000000000000000000000000000000081526004018080602001828103825283818151815260200191508051906020019080838360005b8381101561014f578181015183820152602001610137565b50505050905090810190601f16801561017c5780820380516001836020036101000a031916815260200191505b509250505060405180910390fd5b508080602001905160208110156101a057600080fd5b505194935050505056fea26469706673582212207a913a499405f220fe73d6c33af6d31fa3d6dd38aef5fe5d043818455b8bd55c64736f6c63430007060033000000000000000000000000969d515486ba6133400ac9c73298586426a090f500000000000000000000000000000000000000000000000000000000000000400000000000000000000000000000000000000000000000000000000000000000

Block Transaction Gas Used Reward
Age Block Fee Address BC Fee Address Voting Power Jailed Incoming
Block Uncle Number Difficulty Gas Used Reward
Loading
Make sure to use the "Vote Down" button for any spammy posts, and the "Vote Up" for interesting conversations.